Na}{

File Content: `sysc_sigaltstack.stp`

%( CONFIG_GENERIC_SIGALTSTACK == "n" || kernel_v < "3.8" %?
# sigaltstack ________________________________________________
# long sys_sigaltstack(const stack_t __user *uss, stack_t __user *uoss,
#		struct pt_regs *regs)
# asmlinkage long
# sys32_sigaltstack(const stack_ia32_t __user *uss_ptr,
#		  stack_ia32_t __user *uoss_ptr,
#		  struct pt_regs *regs)
#
# NOTE: args vary between archs.
#

@define _SYSCALL_SIGALTSTACK_NAME
%(
	name = "sigaltstack"
%)

@define _SYSCALL_SIGALTSTACK_ARGSTR
%(
	argstr = sprintf("%s, %p", uss_str, uoss_uaddr)
%)

probe syscall.sigaltstack = dw_syscall.sigaltstack !, nd_syscall.sigaltstack {}
probe syscall.sigaltstack.return = dw_syscall.sigaltstack.return !,
                                   nd_syscall.sigaltstack.return {}

# dw_sigaltstack _____________________________________________________

probe dw_syscall.sigaltstack = kernel.function("sys_sigaltstack").call,
	kernel.function("sys32_sigaltstack").call ?
{
	@_SYSCALL_SIGALTSTACK_NAME
	uss_uaddr = @choose_defined($uss, $uss_ptr)
	uoss_uaddr = @choose_defined($uoss, $uoss_ptr)
# 'regs_uaddr' should have been 'regs'.  Deprecate the old name.
%(systemtap_v <= "1.4" %?
	regs_uaddr = $regs
%)
%(systemtap_v < "2.3" %?
	regs = $regs
%)
	uss_str = (@__compat_task ? _stp_compat_sigaltstack_u(uss_uaddr)
	                          : _stp_sigaltstack_u(uss_uaddr))
	@_SYSCALL_SIGALTSTACK_ARGSTR
}
probe dw_syscall.sigaltstack.return = kernel.function("sys_sigaltstack").return,
	kernel.function("sys32_sigaltstack").return ?
{
	@_SYSCALL_SIGALTSTACK_NAME
	@SYSC_RETVALSTR($return)
}

# nd_sigaltstack _____________________________________________________

probe nd_syscall.sigaltstack = kprobe.function("sys_sigaltstack"),
	kprobe.function("sys32_sigaltstack").call ?
{
	@_SYSCALL_SIGALTSTACK_NAME
	asmlinkage()
	uss_uaddr = pointer_arg(1)
	uoss_uaddr = pointer_arg(2)
%(systemtap_v < "2.3" %?
	regs_uaddr = pointer_arg(3)
	regs = pointer_arg(3)
%)
	uss_str = (@__compat_task ? _stp_compat_sigaltstack_u(uss_uaddr)
	                          : _stp_sigaltstack_u(uss_uaddr))
	@_SYSCALL_SIGALTSTACK_ARGSTR
}
probe nd_syscall.sigaltstack.return = kprobe.function("sys_sigaltstack").return,
	kprobe.function("sys32_sigaltstack").return ?
{
	@_SYSCALL_SIGALTSTACK_NAME
	@SYSC_RETVALSTR(returnval())
}
%)

Name	Size	Permission
aux_syscalls.stp	3665 bytes	0644
sysc_arch_prctl.stp	3594 bytes	0644
sysc_compat_execve.stp	1631 bytes	0644
sysc_compat_fadvise64.stp	8099 bytes	0644
sysc_compat_fallocate.stp	4159 bytes	0644
sysc_compat_ftruncate64.stp	3755 bytes	0644
sysc_compat_lookup_dcookie.stp	4272 bytes	0644
sysc_compat_readahead.stp	3692 bytes	0644
sysc_compat_truncate64.stp	4085 bytes	0644
sysc_execve.stp	1655 bytes	0644
sysc_get_thread_area.stp	3555 bytes	0644
sysc_iopl.stp	2571 bytes	0644
sysc_mmap.stp	4136 bytes	0644
sysc_mmap2.stp	2683 bytes	0644
sysc_pipe32.stp	1572 bytes	0644
sysc_set_thread_area.stp	3499 bytes	0644
sysc_sigaltstack.stp	2296 bytes	0644
sysc_sysctl32.stp	1143 bytes	0644
sysc_vm86_warning.stp	1200 bytes	0644
syscall_num.stp	65658 bytes	0644

File Content: sysc_sigaltstack.stp

File Content: `sysc_sigaltstack.stp`