Na}{

File Content: `io_submit.stp`

#!/usr/bin/stap
#
# Copyright (C) 2007 Oracle Corp. Chris Mason <chris.mason@oracle.com>
#
# This was implemented to find the most common causes of schedule during
# the AIO io_submit call.  It does this by recording which pids are inside
# AIO, and recording the current stack trace if one of those pids is
# inside schedule.
# When the probe exits, it prints out the 30 most common call stacks for
# schedule().
#
# This file is free software. You can redistribute it and/or modify it under 
# the terms of the GNU General Public License (GPL); either version 2, or (at
# your option) any later version.

global in_iosubmit
global traces

/*
 * add a probe to sys_io_submit, on entry, record in the in_iosubmit
 * hash table that this proc is in io_submit
 */
probe syscall.io_submit {
  in_iosubmit[tid()] = 1
}

/*
 * when we return from sys_io_submit, record that we're no longer there
 */
probe syscall.io_submit.return {
  delete in_iosubmit[tid()]
}

/*
 * every time we call schedule, check to see if we started off in
 * io_submit.  If so, record our backtrace into the traces histogram
 */
probe kernel.function("schedule") {
  if (tid() in in_iosubmit) {
    traces[backtrace()] <<< 1

    /*
     * change this to if (1) if you want a backtrace every time
     * you go into schedule from io_submit.  Unfortunately, the traces
     * saved into the traces histogram above are truncated to just a
     * few lines.  so the only way to see the full trace is via the
     * more verbose print_backtrace() right here.
     */
    if (0) {
      printf("schedule in io_submit!\n")
      print_backtrace()
    }
  }
}

probe begin {
  printf("Ready!\n")
}

/*
 * when stap is done (via ctrl-c) go through the record of all the
 * trace paths and print the 30 most common.
 */
probe end {
  foreach (stack in traces- limit 30) {
    printf("%d:", @count(traces[stack]))
    print_syms(stack);
  }
}

Name	Size	Permission
capture_ssl_master_secrets.meta	664 bytes	0644
capture_ssl_master_secrets.stp	1090 bytes	0755
capture_ssl_master_secrets.txt	1907 bytes	0644
deviceseeks.meta	490 bytes	0644
deviceseeks.stp	1292 bytes	0755
deviceseeks.txt	5395 bytes	0644
disktop.meta	381 bytes	0644
disktop.stp	1794 bytes	0755
eatmydata.meta	337 bytes	0644
eatmydata.stp	1188 bytes	0755
eatmydata.txt	304 bytes	0644
enospc.meta	332 bytes	0644
enospc.stp	2318 bytes	0755
inodewatch.meta	475 bytes	0644
inodewatch.stp	245 bytes	0755
inodewatch2.meta	504 bytes	0644
inodewatch2.stp	390 bytes	0755
io_submit.meta	508 bytes	0644
io_submit.stp	1906 bytes	0755
io_submit.tcl	140 bytes	0644
ioblktime.meta	769 bytes	0644
ioblktime.stp	788 bytes	0755
iodevstats.meta	738 bytes	0644
iodevstats.stp	1152 bytes	0755
iodevstats.txt	528 bytes	0644
iostat-scsi.meta	608 bytes	0644
iostat-scsi.stp	4366 bytes	0755
iostat-scsi.txt	481 bytes	0644
iostats.meta	671 bytes	0644
iostats.stp	1154 bytes	0755
iostats.txt	361 bytes	0644
iotime.meta	1024 bytes	0644
iotime.stp	2893 bytes	0755
iotop.meta	410 bytes	0644
iotop.stp	624 bytes	0755
mbrwatch.meta	559 bytes	0644
mbrwatch.stp	234 bytes	0755
mbrwatch.tcl	140 bytes	0644
mbrwatch.txt	788 bytes	0644
nfs_func_users.meta	665 bytes	0644
nfs_func_users.stp	341 bytes	0755
slowvfs.meta	426 bytes	0644
slowvfs.stp	281 bytes	0755
switchfile.meta	330 bytes	0644
switchfile.stp	231 bytes	0644
traceaio.c	2624 bytes	0644
traceaio.meta	331 bytes	0644
traceaio.stp	1825 bytes	0755
traceaio.txt	2761 bytes	0644
traceio.meta	403 bytes	0644
traceio.stp	1384 bytes	0755
traceio2.meta	400 bytes	0644
traceio2.stp	494 bytes	0755
ttyspy.meta	521 bytes	0644
ttyspy.stp	1750 bytes	0755
ttyspy.txt	455 bytes	0644

File Content: io_submit.stp

File Content: `io_submit.stp`